> Tech > Préparation du processus de déploiement de la station

Préparation du processus de déploiement de la station

Tech - Par iTPro - Publié le 21 octobre 2011
email

Pour préparer la clé USB, nous allons tout d’abord la rendre amorçable à l’aide de l’environnement WinPE. Pour cela nous allons télécharger puis installer le package WAIK. Une fois installé, il suffit d’ouvrir une invite de commande WAIK en tant qu’Administrateur. Voir figure 3.

Lancez la

commande pour créer un dossier pour l’environnement WinPE sur votre disque dur :

copype.cmd x64 c:\winpe_64

Copiez le fichier C:\Program Files\Windows AIK\Tools\PETools\x64\winpe.wim dans le répertoire c:\winpe_64\ISO\sourceset renommez le boot.wim.

Copiez dans un répertoirec:\winpe_x64\ISO\StationPack\Restore les images compressées de Windows 7 et Windows Server 2008 R2 au format 7zip avec l’outil 7zip.exe.

Copiez dans un répertoirec:\winpe_x64\ISO\StationPack\Windows\System32 le script RestoreStation.bat suivant qui servira de processus de restauration local :

RestoreStation.bat

X:\Restore\7z465-x64\7z.exe e X:\Restore\Win7.7z -oX:\ -y
X:\Restore\7z465-x64\7z.exe e X:\Restore\Win2008.7z -oX:\ -y
exit


Copiez dans le répertoire c:\winpe_x64\ISO\ les fichiers DeployStation.bat et diskpart.txt avec les contenus suivants (les contenus sont commentés) qui serviront au processus d’installation à partir de la clé USB (Je vous invite particulièrement à étudier ce script) : voir listings 2 et 3.

DeployStation.bat :

echo on
cls

::Initialiser le disque V:
diskpart.exe /s \diskpart.txt

::Applique l'image WinPE sur le disque V:
\StationPack\Restore\imagex.exe /apply \sources\boot.wim 1 v:

::Copie des fichiers d'amorçage
Xcopy \boot\*.* /e /f /y /r v:\boot\
copy \bootmgr v:

::Création d'un bcd temporaire
mkdir v:\temp\
bcdedit /createstore v:\temp\bcd
bcdedit /store v:\temp\bcd /d "Boot Manager" /create {Bootmgr}
bcdedit /store v:\temp\bcd /set {bootmgr} device boot

::Import de la bcd temporaire
bcdedit -import v:\temp\bcd

::Ajout de WinPE
For /F "tokens=3 delims= " %%1 in ('bcdedit /store v:\boot\bcd -create /d "[Restauration v4.1]" -application osloader') do set guid=%%1
bcdedit /store v:\boot\bcd /set %guid% osdevice partition=V:
bcdedit /store v:\boot\bcd /set %guid% device partition=V:
bcdedit /store v:\boot\bcd /set %guid% path \windows\system32\boot\winload.exe
bcdedit /store v:\boot\bcd /set %guid% systemroot \windows
bcdedit /store v:\boot\bcd /set %guid% locale fr-FR
bcdedit /store v:\boot\bcd /set %guid% winpe yes
bcdedit /store v:\boot\bcd /set %guid% detecthal yes
bcdedit /store v:\boot\bcd /displayorder %guid% -addlast
bcdedit /store v:\boot\bcd /default %guid%

::Deploiement des systemes
xcopy \StationPack\*.* /e /f /y /r v:\

::Ajout de Windows 2008 R2
"V:\Restore\7z465-x64\7z.exe" e V:\Restore\Win2008.7z -oV:\ -y
For /F "tokens=7 delims=. " %%1 in ('bcdedit /store v:\boot\bcd /copy {default} /d "Windows 2008 R2 (x64-EN)"') do set guidwin2008=%%1
bcdedit /store v:\boot\bcd /set %guidwin2008% device vhd=[V:]\Win2008.vhd
bcdedit /store v:\boot\bcd /set %guidwin2008% osdevice vhd=[V:]\Win2008.vhd
bcdedit /store v:\boot\bcd /set %guidwin2008% path \Windows\system32\winload.exe
bcdedit /store v:\boot\bcd /set %guidwin2008% locale en-US
bcdedit /store v:\boot\bcd /set %guidwin2008% winpe no
bcdedit /store v:\boot\bcd /set %guidwin2008% systemroot \Windows
bcdedit /store v:\boot\bcd /displayorder %guidwin2008% -addfirst

::Ajout de Windows 7
"V:\Restore\7z465-x64\7z.exe" e V:\Restore\Win7.7z -oV:\ -y
For /F "tokens=7 delims=. " %%1 in ('bcdedit /store v:\boot\bcd /copy {default} /d "Windows 7 (x64-FR)"') do set guidwin7=%%1
bcdedit /store v:\boot\bcd /set %guidwin7% device vhd=[V:]\Win7.vhd
bcdedit /store v:\boot\bcd /set %guidwin7% osdevice vhd=[V:]\Win7.vhd
bcdedit /store v:\boot\bcd /set %guidwin7% path \Windows\system32\winload.exe
bcdedit /store v:\boot\bcd /set %guidwin7% locale fr-FR
bcdedit /store v:\boot\bcd /set %guidwin7% winpe no
bcdedit /store v:\boot\bcd /set %guidwin7% systemroot \Windows
bcdedit /store v:\boot\bcd /displayorder %guidwin7% -addfirst
bcdedit /store v:\boot\bcd /default %guidwin7%


diskpart.txt


select disk=0
select partition=1
clean
create partition primary
active
format fs=ntfs quick
assign letter=v

Téléchargez gratuitement cette ressource

Guide de Services Cloud Managés

Guide de Services Cloud Managés

Accélérer votre transformation digitale, protéger et sécuriser vos environnements Cloud avec les offres de support, d'accompagnement et de services managés. Découvrez le TOP 3 des Services Managés pour accompagner la transformation de vos environnements Cloud, gagner en agilité et en sécurité dans un monde d'incertitudes.

Tech - Par iTPro - Publié le 21 octobre 2011